Cara buat progres Bar Ms.Acces

WONG Gaptex 

Nulis Artikel di Blog Gratisan,,, !!!

Sering kita lihat dalam beberapa program ketika awal kita menjalankan program...terdapat progress atau beberapa waktu sebelum program tersebut masuk ke dalam program utamanya... atau yang biasa kita sebut "Loading....." Sebenarnya penggunaan progres bar di Microsoft Acces tidaklah begitu penting. Namun dari pada melamun alangkah baik saya membuat postingan yang mungkin bermanfaat bagi yang lagi mencarinya. Printscreem dibawah adalah Progres Bar yang akan saya bahas pada tema ini.

Tahap Pertama. Pilih Create >> Form Design >> maka tampil form yang kosong seperti gambar dibawah ini, jika ingin mempercantik halamannya saya persilahkan, saya memilih warna biru untuk backgroundnya. Sebelum melanjut tahap selanjutnya persiapkan dulu alat yang dibutuhkan untuk proses pembuat seperti pada judul postingan. Siapkan satu buah Gambar.jpg, Rectangle dan label. buat seperti contoh pada gambar berikutnya:

Tahap Ke dua. Ini tampilan yang saya buat untuk proses kebutuhan seperti pada judul postingan. Penjelasan tentang gambar dibawah : angka 1 adalah gambar, angka 2 Label yang sudah saya edit dengan caption Loading data dan angka 3 Retangle / boxs yang nantinya saya ubah sesuai dengan soucre code

Tahap Ke tiga. Perhatikan gambar dibawah ini, angka 1 dan 2, Klik pada property sheet, pilih All Name gambar saya ubah menjadi Box20

Tahap Ke empat. Perhatikan gambar dibawah ini, angka 1 dan 2, Klik pada property sheet, pilih All Name rectangle saya ubah menjadi Box21

Tahap Ke Lima. Perhatikan gambar dibawah ini, angka 1 dan 2, Klik pada property sheet, pilih All Name Label saya ubah menjadi label22

Tahap Ke Enam. Perhatikan gambar dibawah Pilih View Code

Tahap Ke Tujuh. Perhatikan gambar dibawah ini: angka 1adalah soucre code yang sudah saya buatkan untuk form dan angka 2 soucre code untuk module nya.

Soucre Code vba untuk Form

Option Compare Database
Option Explicit
Dim l As Long
Dim lbarlnth As Long

'Alter value below to change speed
Const Steplth = 120

Private Sub Form_load()
On Error GoTo Err_Form_Load

    lbarlnth = Me.Box21.Width - 2
l = 0

Exit_Form_Load:
   Exit Sub

Err_Form_Load:
    MsgBox Err.Description
    Resume Exit_Form_Load

End Sub

Private Sub Form_Timer()
On Error GoTo Err_Form_Timer

Do Until l >= lbarlnth
    Call RunProgressBar(l)
    l = l + Steplth
    Pause 0.01
Loop

Pause 2
DoCmd.Close acForm, Me.Name

Exit_Form_Timer:
   Exit Sub

Err_Form_Timer:
    MsgBox Err.Description
    Resume Exit_Form_Timer

End Sub

Soucre Code vba untuk module

Option Compare Database
Option Explicit

Function RunProgressBar(lLth As Long)

If IsLoaded("Loading") Then
    Forms!Loading!Box20.Width = lLth
End If

End Function

Function IsLoaded(ByVal strFormName As String) As Boolean
On Error GoTo Err_IsLoaded

    Const conObjStateClosed = 0
    Const conDesignView = 0

    If SysCmd(acSysCmdGetObjectState, acForm, strFormName) <> conObjStateClosed Then
        If Forms(strFormName).CurrentView <> conDesignView Then
            IsLoaded = True
        End If
    End If

Exit_IsLoaded:
   Exit Function

Err_IsLoaded:
    MsgBox Err.Description, , " Service Operations"
    Resume Exit_IsLoaded

End Function

Public Function Pause(NumberOfSeconds As Variant)
On Error GoTo Err_Pause
    
    Dim PauseTime As Variant, Start As Variant
    
    PauseTime = NumberOfSeconds
    Start = Timer
    Do While Timer < Start + PauseTime
    DoEvents
    Loop
    
Exit_Pause:
    Exit Function
    
Err_Pause:
    MsgBox Err.Number & " - " & Err.Description
    Resume Exit_Pause
    
End Function

Link DOWNLOAD DATA MASTER